:If Ans=0
:Goto 0
:If Ans=1
:Goto 1
:If Ans=2
:Goto 2
:If Ans=3
:Goto 3
:If Ans=4
:Goto 4
:If Ans=5
:Goto 5
:If Ans=6
:Goto 6
:If Ans=7
:Goto 7
:If Ans=8
:Goto 8
:Return
:Lbl 0
:AxesOff
:FnOff 
:ZoomSto
:0→Xmin
:0→Ymax
:94→Xmax
:{-}62→Ymin
:ClrDraw
:3→A
:While A≠2
:If A=3
:1
:If A=0 or A=1
:2
:If A=6
:4
:If A=5
:6
:If A=8
:7
:If A=9
:8
:prgmMIND22GO
:End
:ClrDraw
:ZoomRcl
:FnOn 
:AxesOn
:DelVar ADelVar BDelVar CDelVar DDelVar EDelVar FDelVar GDelVar HDelVar IDelVar JDelVar KDelVar LDelVar ODelVar XDelVar YDelVar Str1DelVar {L1}DelVar {L2}DelVar {L4}DelVar {L3}DelVar Str2DelVar Q
:ClrHome
:Output(1,1," 
:Return
:Lbl 1
:ClrDraw
:Text({-}1,1,18,"MASTERMIND
:Text(9,33,"By Kaslai
:Text(56,19,"TI-Concours 2013
:Text(22,30,"One Player
:Text(30,27,"Two Players
:Text(38,41,"Quit
:DelVar A
:DelVar K
:While 1
:Text({-}1,0,90," 
:If K=22
:Then
:2→A
:Return
:End
:If K=25 and A>0
:A-1→A
:If K=34 and A<2
:A+1→A
:Text({-}1,0,90," 
:If A=0
:Then
:Text(22,26,">
:Text(22,66,"<
:Else
:Text(22,26,"   
:Text(22,66,"   
:End
:Text({-}1,0,90," 
:If A=1
:Then
:Text(30,23,">
:Text(30,68,"<
:Else
:Text(30,23,"   
:Text(30,68,"   
:End
:Text({-}1,0,90," 
:If A=2
:Then
:Text(38,37,">
:Text(38,54,"<
:Else
:Text(38,37,"   
:Text(38,54,"   
:End
:Text({-}1,0,90," 
:If K=105
:Then
:A
:Return
:End
:getKey→K
:While K=0
:getKey→K
:Text({-}1,0,90," 
:End
:End
:Return
:Lbl 2
:A→C
:ClrDraw
:Text({-}1,1,26,"OPTIONS
:Text(20,40,"Pegs
:Text(36,39,"Tries
:Text(52,33,"Continue
:0→A
:4→D
:12→E
:DelVar K
:While 1
:If A=0
:Then
:If D>2 and D<8
:Text(26,41,"< ",D," >
:If D=2
:Text(26,41,"     ",D," >
:If D=8
:Text(26,41,"< ",D,"    
:Else
:Text(26,41,"     ",D,"     
:End
:If A=1
:Then
:If E>10 and E<24
:Text(42,39,"< ",E," >
:If E=10
:Text(42,39,"     ",E," >
:If E=24
:Text(42,39,"< ",E,"    
:Else
:Text(42,39,"     ",E,"    
:End
:If A=2
:Then
:Text(52,29,">Continue<
:Else
:Text(52,29,"    Continue    
:End
:getKey→K
:While K=0
:getKey→K
:Text({-}1,0,90," 
:End
:If K=22
:Then
:2→A
:Return
:End
:If K=24 and A=0 and D>2
:D-1→D
:If K=24 and A=1 and E>10
:E-1→E
:If K=26 and A=0 and D<8
:D+1→D
:If K=26 and A=1 and E<24
:E+1→E
:If K=25 and A>0
:A-1→A
:If K=105 and A=2
:Then
:5+C→A
:Return
:End
:If A<2 and (K=34 or K=105
:A+1→A
:End
:Return
:Lbl 3
:(94-D*10-12)/2→C
:Line(C,{-}49,C+D6+6,{-}49
:Line(C,{-}61,C+D6+6,{-}61
:Line(C,{-}49,C,{-}61
:Line(C+D6+6,{-}49,C+D6+6,{-}61
:For(A,0,D-1
:Text(52,C+4+A*6,{L1}(A+1
:End
:DelVar KDelVar A
:While 1
:C+4+A*6→B
:Line(B,{-}51,B+2,{-}51
:Line(B,{-}59,B+2,{-}59
:Pxl-On(50,B+1
:Pxl-On(60,B+1
:getKey→K
:While K=0
:Text({-}1,0,90," 
:getKey→K
:End
:If K=22
:Then
:2→A
:Return
:End
:If K=24
:Then
:Pt-Off(B+1,{-}51,3
:Pt-Off(B+1,{-}59,3
:A-1→A
:End
:If K=26
:Then
:Pt-Off(B+1,{-}59,3
:Pt-Off(B+1,{-}51,3
:A+1→A
:End
:If A<0
:D+A→A
:If A≥D
:A-D→A
:If K=25
:{L1}(A+1)+1→{L1}(A+1
:If K=34
:{L1}(A+1)-1→{L1}(A+1
:If {L1}(A+1)<0
:10+{L1}(A+1)→{L1}(A+1
:If {L1}(A+1)>9
:{L1}(A+1)-10→{L1}(A+1
:If K=105
:Then
:DelVar A
:Pt-Off(B+1,{-}59,3
:Pt-Off(B+1,{-}51,3
:Return
:End
:If K>71 and K<75
:K-65→{L1}(A+1
:If K>81 and K<85
:K-78→{L1}(A+1
:If K>91 and K<95
:K-91→{L1}(A+1
:If K=102
:0→{L1}(A+1
:If K>71 or K=25 or K=34 or K=102
:Text(52,B,{L1}(A+1
:End
:Return
:Lbl 4
:ClrDraw
:Text({-}1,1,6,"ENTER THE CODE
:{0}→{L1}
:D→dim({L1}
:DelVar A
:3
:prgmMIND22GO
:If A=2
:Return
:{L1}→{L3}
:5
:prgmMIND22GO
:Return
:Lbl 5
:"                                                  "→Str2
:ClrDraw
:{0}→{L1}
:D→dim({L1}
:" "→Str1
:DelVar F
:While 1
:Text(53,66,"Tries:",E-F,"      "
:DelVar GDelVar H
:(94-D*10-12+6)/2→C
:If F>8
:Then
:F-8→H
:sub(Str1,51,400)→Str1
:End
:While G<8 and G<F
:Text(42-6G,C,sub(Str1,(F-G-H-1)*50+1,50),Str2
:G+1→G
:End
:If A=D
:Then
:8→A
:Return
:End
:If E-F<1
:Then
:9→A
:Return
:End
:DelVar A
:3
:prgmMIND22GO
:If A=2
:Return
:Str1+" "→Str1
:If Str1="  "
:" "→Str1
:For(A,1,D
:Str1+sub("0123456789",{L1}(A)+1,1)+"  "→Str1
:End
:Str1+"       "→Str1
:{L3}→{L4}
:DelVar A
:For(I,1,D
:cumSum(cumSum(seq({L4}(J)={L1}(I),J,1,D→{L2}
:{L4}+({L2}=1)*{-}99→{L4}
:A+sum({L2}=1→A
:End
:sum({L1}={L3}→O
:A-O→K
:O→A
:Str1+sub(" {cross}{cross}{cross}{cross}{cross}{cross}{cross}{cross}",1,O+1)+sub(" {dot}{dot}{dot}{dot}{dot}{dot}{dot}{dot}",1,K+1→Str1
:Str1+sub(Str2,1,50*(F-H+1)-length(Str1))→Str1
:F+1→F
:End
:Return
:Lbl 6
:D→dim({L3}
:For(A,1,D
:randInt(0,9)→{L3}(A
:End
:5
:prgmMIND22GO
:Return
:Lbl 7
:ClrDraw
:Text({-}1,1,23,"YOU WIN!
:Text(8,23,"It took ",F," tries.
:Text(55,7,"Press [ENTER] to continue
:Pause 
:3→A
:Return
:Lbl 8
:ClrDraw
:Text({-}1,1,0,"CODE MAKER WINS!
:Text(55,7,"Press [ENTER] to continue
:Pause 
:3→A
:Return