ACTOR "8ga SX-10 Shotgun" : BrutalWeapon Replaces Shotgun
{
	Weapon.AmmoGive2 4
	Weapon.AmmoType1 "ShotgunAmmo"
	Weapon.AmmoType2 "Shell"

	Weapon.SlotNumber 3
	Weapon.SlotPriority 0
	Weapon.UpSound "weapons/sgpump"

	Inventory.PickupSound "weapons/sgpump"
	Inventory.PickupMessage "\c[WHITE]SHOTGUN"

	Obituary "%o was blasted with %k's shotgun."
	AttackSound "weapons/sg"

	+WEAPON.AMMO_CHECKBOTH
	States
	{
	Spawn:
		SHTC A -1
		Stop

	Select:
		TNT1 A 0 A_GiveInventory("Selecting",1)
		TNT1 A 0 A_Raise
		Wait
	SelAnimate:
		SHTG A 1 Offset(32,64)
		SHTG A 1 Offset(24,48)
		SHTG A 1 Offset(16,40)
		SHTG A 1 Offset(8,30)
		TNT1 A 0 A_TakeInventory("Selecting",1)
	Ready:
		TNT1 A 0 A_JumpIfInventory("Selecting",1,"SelAnimate")
		TNT1 A 0 A_JumpIfInventory("Reloading",0,"Reload")
		SHTG A 1 A_WeaponReady
		Loop
	Deselect:
		SHTG A 1 Offset(8,30)
		SHTG A 1 Offset(16,40)
		SHTG A 1 Offset(24,48)
		SHTG A 1 Offset(32,64)
		TNT1 A 1 A_Lower
		Wait
	Fire:
		TNT1 A 0 A_JumpIfInventory("ShotgunAmmo",1,1)
		Goto Reload
		TNT1 AA 0 A_FireCustomMissile("SmokeSpawner",0,0,0,5)
		TNT1 AAAAAAAA 0 A_FireCustomMissile("Tracer", random(-5,5), 0, -1, random(-5,5))
		SHTF A 1 BRIGHT A_FireCustomMissile("YellowFlareSpawn",0,0,0,0)
		SHTF A 1 BRIGHT Radius_Quake(6,4,0,2,0)
		SHTF B 1 BRIGHT A_FireBullets (3,2,8,7,"ShotgunPuff")
		SHTF CDE 1
		SHTG A 3 A_GiveInventory("Pumping", 1)
		SHTG BCDEF 1
		SHTG G 1 A_FireCustomMissile("ShotCaseSpawn",0,0,-4,-4)
		SHTG H 1 A_PlaySound("weapons/sgpump", 7)
		SHTG IJKLKJIHGFEDCB 1
		SHTG A 1 Offset(10,36)
		SHTG A 1 Offset(0,32)
		Goto Ready

	Reload:
		SHTG A 1 A_WeaponReady
		TNT1 A 0 A_JumpIfInventory("Shell",1,1)
		Goto Ready
		SHTG BCDEFGH 1
		TNT1 A 0 A_JumpIfInventory("ShotgunAmmo",0,"ReloadDone")
		TNT1 A 0 A_JumpIfInventory("Shell",1,"Reloading")
		Goto ReloadDone
	Reloading:
		TNT1 A 0 A_JumpIfInventory("ShotgunAmmo",0,"ReloadDone")
		TNT1 A 0 A_JumpIfInventory("Shell",1,1)
		Goto ReloadDone
		SSHR ABC 1
		SSHR D 1 A_PlaySound("insertshell",6)
		SSHR E 1 A_GiveInventory("ShotgunAmmo",1)
		SSHR F 1 A_TakeInventory("Shell",1)
		SSHR G 1
		Goto Reloading
	ReloadDone:
		SHTG I 1 A_PlaySound("weapons/sgpump")
		SHTG J 1 A_GiveInventory("Pumping",1)
		SHTG KLKJIHGFEDCB 1
		SHTG A 1 A_TakeInventory("Pumping",1)
		Goto Ready
	}
}